elapsed
Museo Nacional de Bellas Artes
Instalación.
Microcomputador Atari 800XL, cassetera y controles de paddle, televisor color modelo 1984.
elapsed es una pequeña aplicación de dibujo visual y sonoro programada en BASIC, ejecutándose en un Atari 800XL.
El programa refiere la mecánica de un reloj, mediante la anidación de ciclos que son representados como patrones visuales y trazados sonoramente.
La interacción con el usuario permite la modificación de los parámetros de iteración, produciendo alteraciones en las secuencias originales. Este ruido o interferencia sobre la señal original es retroalimentado por la aplicación que ajusta su comportamiento/despliegue a estas nuevas condiciones "ambientales".
(Podemos entender como ruido a cualquier información (no deseada) en un canal de comunicación y que no sea parte del mensaje intencional)
elapsed opera en el tiempo, utilizando el sonido como soporte para la experiencia sensible y lineal de procesos abstractos y no lineales.
 |
150 DIM TONES(36)
160 FOR I=0 TO 35:READ T:TONES(I)=T:NEXT I
170 DIM SCALE0(8), SCALE1(8)
180 FOR I=0 TO 7:READ T:SCALE0(I)=T:NEXT I
190 FOR I=0 TO 7:READ T:SCALE1(I)=T:NEXT I
200 CS=0:BASETONE=0
210 BCOUNT=0
300 GRAPHICS 0
305 POKE 16,112:POKE 53774, 112
310 POKE 710,0
1000 F0=(228-PADDLE(0))/228:T0=NOT PTRIG(0)
1010 F1=PADDLE(1)/228:T1=NOT PTRIG(1)
1020 BASETONE=INT(35*F0)
1025 BTMP=2^INT(7*F1)
1030 BCOUNT=BCOUNT+1
1040 ENABLECS=0
1050 IF BCOUNT>BTMP THEN ENABLECS=1:BCOUNT=0
1900 GOSUB 8000
1910 GOSUB 9000
1990 GOTO 1000
7999 REM BASES
8000 CTONE=BASETONE+SCALE0(CS)
8005 HTONE=BASETONE+SCALE1(DS)
8007 RTONE=BASETONE+SCALE1(INT(RND(0)*7))
8010 IF CTONE>35 THEN CTONE=CTONE-36
8011 IF HTONE>35 THEN HTONE=HTONE-36
8012 IF RTONE>35 THEN RTONE=RTONE-36
8014 SOUND 0,TONES(RTONE),10,8*INT(RND(0))
8016 SOUND 1,TONES(HTONE),10+T1*2,8
8018 SOUND 2,TONES(BASETONE),10,6
8020 SOUND 3,TONES(CTONE),10+T0*2,8
8030 DS=DS+1:IF DS>7 THEN DS=0
8040 IF ENABLECS THEN CS=CS+1:IF CS>7 THEN CS=0
8050 RETURN
8999 REM SCREEN
9000 POSITION 2+CTONE+T0,CS
9010 ? #6;CHR$(CTONE)
9020 POSITION 2+HTONE+T1,CS+8
9030 ? #6;CHR$(HTONE)
9040 POSITION 2+RTONE,DS+16
9050 ? #6;CHR$(RTONE)
9100 IF NOT T0 THEN POKE 712,HTONE:POKE 710,HTONE
9110 IF NOT T1 THEN POKE 709,RTONE
9999 RETURN
10020 REM TONES
10030 DATA 243, 230, 217, 204, 193, 182, 173, 162, 153, 144, 136, 128
10040 DATA 121, 114, 108, 102, 96, 91, 85, 81, 76, 72, 68, 64
10050 DATA 60, 57, 53, 50, 47, 45, 42, 40, 37, 35, 33, 31
10060 REM SCALE 0
10070 DATA 0, 12, 5, 6, 7, 12, 3, 5
10080 REM SCALE 1
10090 DATA 0, 12, 0, 12, 5, 3, 0, 5
------------------------------
Para iniciar la aplicación:
1.- Encienda el televisor.
2.- Seleccione el canal 3.
3.- Encienda el microcomputador. En la pantalla aparecerá la palabra “READY”.
4.- Inserte el cassete <VOODOOCHILD>:ELAPSED
en la cassetera.
5.- Rebobine completamente la cinta y ponga el contador en “000”.
6.- Adelante la cinta hasta q el contador indique “003”.
7.- Tipee “CLOAD” y presione RETURN.
8.- Presione PLAY en la cassetera y vuelva a presionar RETURN en el computador. El programa comenzará a cargarse.
9.- En caso de error de carga aparecerá un mensaje en la pantalla. Vuelva a intentar desde el paso 5.
9.- Cuando el programa se haya cargado aparecerá la palabra “READY” en pantalla.
Para ejecutar la aplicación:
10- Tipee “RUN” y presione RETURN. La aplicación se ejecutará.
Para interactuar con la aplicación:
11.- Utilice los controladores de paleta disponibles (paddles) para modificar los parámetros de despliegue.